set terminal epslatex size 3.5,1.25
set output "baro_setup_issue.eps"

unset arrow

set yrange[980.5:981.5]
set xrange[0:50]
set ytics 980.5, 0.2, 981.5

set lmargin 6.0
set rmargin 1.0
set tmargin 0.5
set bmargin 0.1

# strange! why bmargin so small? otherwise huge gaps in TeX?

set xtics nomirror
set ytics nomirror

set format y "\\footnotesize{\\SI{%.1f}{\\hpa}}"
set format x "\\footnotesize{\\SI{%.0f}{\\second}}"

set object 1 rectangle from      0,980.5 to  4.000,981.5 fs solid noborder fc rgb "#EEEEEE" behind
set object 2 rectangle from  4.000,980.5 to 10.000,981.5 fs solid noborder fc rgb "#DDDDDD" behind
set object 3 rectangle from 10.000,980.5 to 36.000,981.5 fs solid noborder fc rgb "#EEEEEE" behind
set object 4 rectangle from 36.000,980.5 to 48.000,981.5 fs solid noborder fc rgb "#DDDDDD" behind

set label 1 "\\small{error}"						at 1.800,981.44 right front rotate by 90
set label 2 "\\small{estimation}"					at 6.900, 981.44 right front  rotate by 90
set label 3 "\\small{walking along the hallway}"	at 22.900, 981.4 center front 
set label 4 "\\small{stair}"						at 41.800, 981.4 center front
plot "baro_setup_issue.csv" using ($2/1000):4 with lines notitle lw 2 lc rgb "#000099"
